#include "colors.inc"
#include "stones.inc"
#include "metals.inc"
#include "textures.inc"
#include "glass.inc"

camera {
	location <-6,3,-10>
//	location <-0,2,-3>
	look_at <0,0,0>
	rotate <0,-360*clock,0>
}


#declare Table = merge {
	box { <-5,-0.5,-3>, <5,0.5,3> }

	cylinder { <-4.5+0.75, 0, 2.5-0.75>, <-4.5+0.75, -15, 2.5-0.75>, 0.75 }
	cylinder { <4.5-0.75, 0, 2.5-0.75>, <4.5-0.75, -15, 2.5-0.75>, 0.75 }
	cylinder { <-4.5+0.75, 0, -2.5+0.75>, <-4.5+0.75, -15, -2.5+0.75>, 0.75 }
	cylinder { <4.5-0.75, 0, -2.5+0.75>, <4.5-0.75, -15, -2.5+0.75>, 0.75 }
}

#declare Kuutio = union {
	box {
		<0,0,0>, <10,10,10>
		rotate <-45,0,35.26439>
		scale 0.1
		texture { pigment { Jade } }
	}

	intersection {
		sphere {
			<0,0,0>, 0.4
		}

		box { <-5,0,-5>, <5,5,5> }

		texture { pigment { DMFDarkOak } }
	}
	scale 1.2
}


#declare Pyramidi = difference {
	difference {
		difference {
			difference {
				box { <0,0,0>, <10,10,10> }
				box { <0,-1,-1>, <-10,11,20> rotate 30*y }
				translate <-10,0,0>
			}

			box { <0,-1,-1>, <20,11,20> rotate -30*y }
			box { <-11,-1,0>, <1,20,-15> rotate 19.47122*x }
			translate <5,0,-sqrt(75)/3>
			rotate 120*y
			translate <0,0,sqrt(75)/3>
		}


		box { <-5,0,0>, <5,15,-10> rotate 19.47122*x }
		translate <0,0,-sqrt(75)/3>
		rotate 120*y
		translate <0,0,sqrt(75)/3>
	}
	box { <-5,0,0>, <5,15,-10> rotate 19.47122*x }

	translate <0,0,-sqrt(75)/3>

	texture {
		pigment {
			gradient y
			color_map {
				[0.0 color Tan]
				[0.8 color Tan]
				[0.9 color Brown]
				[1.0 color Tan]
			}
		}
		normal { bumps 0.4 scale 0.2 }

	}
	scale 0.2
}


#declare RedGem = sphere {
	<0,0,0>, 1
	texture {
		NBglass
		pigment { rgbf <0.9, 0.1, 0.2, 0.85> }
		finish { ambient 1.95 }
	}
    scale <0.1,0.2,0.1>
}


#declare Muki = difference {
	merge {
		cone {
			<0,0,0>, 5, <0,2,0>, 6
		}

		cone {
			<0,2,0>, 6, <0,14,0>, 5
		}

		cylinder {
			<0,2,0>, <0,3,0>, 6.1
		}

		cylinder {
			<0,3.3,0>, <0,4.3,0>, 6.05
		}

		cylinder {
			<0,11,0>, <0,12,0>, 5.4
		}

		blob {
			threshold 0.2
			cylinder {
				<5.5,11.5,0>, <8,11.7,0>, 0.8, 1
			}
			cylinder {
				<8,11.2,0>, <9,7,0>, 0.8, 1
			}

			cylinder { <9,6.8,0>, <9,6,0>, 0.8, 1 }
			cylinder { <9,5.8,0>, <8.5,5,0>, 0.8, 1 }
			cylinder { <8.4,4.8,0>, <7.5,4,0>, 0.8, 1 }
			cylinder { <7.3,3.8,0>, <6,3.8,0>, 0.8, 1 }

			//translate <1,0,0>
		}
	}

	cylinder { <0,0.7,0>, <0,15,0>, 4.7 }

	scale 0.1
}

#declare Flame = object {
	blob {
		threshold 0.5
		sphere { <0,0,0>, 2, 1 }
		sphere { <0,2,0>, 2, 0.5 }
	}

	texture {
		finish { ambient 1 diffuse 0 reflection 0 }
		pigment {
			gradient y
			color_map {
				[0.0 color rgbt <0,0,0,1>]
				[0.1 color rgbt <0,0,0.8,0.8>]
				[0.2 color rgbt <1,1,0,0.1>]
				[0.4 color rgbt <1,1,0,0.3>]
				[0.6 color rgbt <1,0.4,0,0.5>]
				[1.0 color rgbt <0,0,0,1>]
			}
		}
		translate -1.31*y
		scale 3.6
	}

	scale <0.5,1,0.5>
}


#declare Candle = union {
	merge {
		cone {
			<0,0,0>, 4, <0,2,0>, 0
		}

		cylinder {
			<0,1,0>, <0,10,0>, 0.5
		}

		cone {
			<0,10,0>, 0.5, <0,11,0>, 1.5
		}

		cylinder {
			<0,11,0>, <0,13,0>, 1.5
		}

		intersection {
			difference {
				cone { <0,0,0>, 0, <0,2,0>, 8 }
				cone { <0,0.5,0>, 0, <0,2.5,0>, 8 }
			}
			cylinder { <0,-1,0>, <0,2,0>, 3 }

			translate 6*y
		}

		texture { Gold_Metal }
	}

	cylinder {
		<0,13,0>, <0,20,0>, 1.3
		texture { pigment { White } }
		texture {
			pigment {
				gradient y
				color_map {
					[0.0 color rgbt <0,0,0,1>]
					[0.6 color rgbt <0,0,0,1>]
					[1.0 color rgbt <1,1,1,0>]
				}
			}
			finish { ambient 0.7 }
			scale 7
			translate -y
		}
	}

	cylinder {
		<0,20,0>, <0,21,0>, 0.1
		pigment { Gray10 }
	}

	light_source {
		<0,21,0>
		color rgb <1,1,0.8>
		area_light <1.2,0,0>, <0,0,1.2>, 4, 4
		adaptive 1
	//	jitter
		looks_like { Flame }
	}

	scale 0.1
}

light_source {
	<0,-100,0>
	color White
	rotate <-96,4,0>
	spotlight
	radius 10
	falloff 20
	point_at <0,0,0>
}


union {
	object { Table texture { T_Stone8 finish { reflection 0.6 ambient <0.02, 0.02, 0.05>} } translate -0.5*y }

	object { Candle translate <4.0,0,-2.0> }

	merge {
		object {
			Muki
			texture {
				//NBoldglass
				Glass3
			}
		}

		cylinder {
			<0,0.701,0>, <0,9,0>, 4.699
			texture {
				pigment { rgbf <0.2, 0.2, 0.99, 0.9> }
			    finish {
			        ambient 1.0
			        reflection .25
			    }
			}
			interior { ior 1.33 }
			scale 0.1
		}

		rotate 35*y
		translate <-1.5,0,-1.5>
	}

	sphere {
		<-3,1,0>, 1
		texture { Copper_Texture }
	}


	object { Kuutio translate <3,-0.01,0> }

	difference {
		object { Pyramidi }
		cone { <0,sqrt(200/3)-2, 0>, 0, <0,sqrt(200/3)+1 , 0>, 1
			pigment { Tan }
			normal { bumps 0.4 scale 0.2 }
			scale 0.2
		}
		rotate -10*y
	}


	light_source { <0,1.65,0> color Red*0.3 }

	light_source {
		<0,1.65,0>
		color Red
		spotlight
		radius 5
		falloff 7
		tightness 10
		point_at <0,0,-2>
		looks_like { RedGem }
	}

	cone {
		<0,0,0>, 0, <0,0,-2>, 0.26
		open
		texture {
			pigment {
				gradient z
				color_map {
					[0.0 color rgbf <1,0,0,0.6> ]
					[0.8 color rgbf <1,1,1,1> ]
					[1.0 color rgbf <1,1,1,1> ]
				}
			}
			finish { ambient 1.0 diffuse 0 }
			scale 2
		}
		interior { ior 1.0 }
		no_shadow
		hollow
		rotate -39.5*x
		translate 1.65*y
	}

}



plane {
	y, -2
	texture { Water scale <7,6,7> }
}

plane {
	y, -10
	pigment { White }
}


sky_sphere {
	pigment {
		// texture pigment/normal pattern
		bozo // use color map to swirl colors
		// color_map...
		turbulence 0.04
		color_map {
			[0.0 0.01 color rgb <1,1,1> color rgbt <0.0, 0.0, 0.0, 1>]
			[0.01 1.0 color rgbt <1,1,1,1> color rgbt <1,1,1,1>]
		}
		scale 0.001
	}

	pigment {
		gradient y
		color_map {
			[0.000 0.001 color rgb <1.0, 1.0, 1.0> color rgb <0.5, 0.5, 0.5> ]
			[0.001 0.0015 color rgb <0.0, 0.0, 0.0> color rgb <0.4, 0.4, 0.4> ]
			[0.0015 0.004 color rgb <0.4, 0.4, 0.4> color rgbt <1,1,1,1> ]
		}
		scale 1
		translate -1
	}



	rotate <-96,4,0>
}